100 REM CHASE
110 REM AUTHOR: UNKNOWN
120 REM MODIFIED TO RUN ON HONEYWELL 600/6000 BY BILL COTTER
121 REM 2024-03-13: Modified for GW-BASIC by Eric Parent
130 PRINT"YOU ARE WITHIN THE WALLS OF A HIGH VOLTAGE MAZE"
140 PRINT"THERE ARE FIVE SECURITY MACHINES TRYING TO DESTROY YOU"
150 PRINT"YOU ARE THE '*'      THE INTERCEPTORS ARE THE '+'"
160 PRINT"THE AREAS MARKED 'X' ARE HIGH VOLTAGE"
170 PRINT"YOUR ONLY CHANCE FOR SURVIVAL IS TO MANUVER EACH "
180 PRINT"INTERCEPTOR INTO AN 'X'. ---- GOOD LUCK ----"
190 PRINT"MOVES ARE:  1.2.3":PRINT"            8.*.4"
200 PRINT"            7.6.5":PRINT
210 DIM A(10,20),N(2)
220 FOR B=1 TO 10
230 FOR C=1 TO 20
240 LET X=INT(10*RND)
250 IF X=5 THEN 280
260 LET A(B,C)=ASC(" ")
270 GOTO 290
280 LET A(B,C)=ASC("X")
290 NEXT C
300 NEXT B
310 FOR D=1 TO 10
320 LET A(D,1)=ASC("X")
330 NEXT D
340 FOR E=1 TO 10
350 LET A(E,20)=ASC("X")
360 NEXT E
370 FOR F=1 TO 20
380 LET A(1,F)=ASC("X")
390 NEXT F
400 FOR G=1 TO 20
410 LET A(10,G)=ASC("X")
420 NEXT G
430 GOTO 500
440 LET H=INT(1+(10*RND)):IF H>10 THEN 440
450 LET I=INT(1+(20*RND)):IF I>20 THEN 450
460 IF A(H,I)=ASC("X") THEN 440
470 IF A(H,I)=ASC("*") THEN 440
480 IF A(H,I)=ASC("+") THEN 440
490 RETURN
500 GOSUB 440
510 LET A(H,I)=ASC("*"):LET J=H:LET K=I
520 GOSUB 440
530 LET A(H,I)=ASC("+"):LET L=H:LET M=I
540 GOSUB 440
550 LET A(H,I)=ASC("+"):LET N=H:LET O=I
560 GOSUB 440
570 LET A(H,I)=ASC("+"):LET P=H:LET Q=I
580 GOSUB 440
590 LET A(H,I)=ASC("+"):LET R=H:LET S=I
600 GOSUB 440
610 LET A(H,I)=ASC("+"):LET T=H:LET U=I
620 N(0)=1
630 FOR D2=1 TO 10
640 FOR B2=1 TO 20
650 REM N(1)=A(D2,B2):CHANGE N TO N$:PRINT N$:
651 PRINT CHR$(A(D2,B2));
660 NEXT B2
670 PRINT
680 NEXT D2
690 INPUT Y:IF Y=0 THEN 800
700 LET V=J:LET W=K
710 ON Y GOTO 720,730,740,750,760,770,780,790
720 LET J=J-1:LET K=K-1:GOTO 800
730 LET J=J-1:GOTO 800
740 LET J=J-1:LET K=K+1:GOTO 800
750 LET K=K+1:GOTO 800
760 LET J=J+1:LET K=K+1:GOTO 800
770 LET J=J+1:GOTO 800
780 LET J=J+1:LET K=K-1:GOTO 800
790 LET K=K-1
800 IF A(J,K)=ASC("X") THEN 1160
810 LET A(V,W)=ASC(" "):LET A(J,K)=ASC("*")
820 GOTO 940
830 IF A(X,Y)=ASC("X") THEN 910
840 LET V=X:LET W=Y
850 LET X=SGN(J-X):LET Y=SGN(K-Y)
860 LET X=X+V:LET Y=Y+W
870 IF A(X,Y)=ASC("*") THEN 920
871 IF A(X,Y)=ASC(" ") THEN 890
880 LET A(V,W)=ASC(" "):RETURN
890 LET A(X,Y)=ASC("+")
900 LET A(V,W)=ASC(" ")
910 RETURN
920 PRINT "*** YOU HAVE BEEN DESTROYED BY A LUCKY COMPUTER ***"
930 GO TO 1180
940 LET X=L:LET Y=M:GOSUB 830
950 LET L=X:LET M=Y
960 LET X=N:LET Y=O:GOSUB 830
970 LET N=X:LET O=Y
980 LET X=P:LET Y=Q:GOSUB 830
990 LET P=X:LET Q=Y
1000 LET X=R:LET Y=S:GOSUB 830
1010 LET R=X:LET S=Y
1020 LET X=T:LET Y=U:GOSUB 830
1030 LET T=X:LET U=Y
1040 IF A(L,M)=ASC("X") THEN 1060
1050 GOTO 630
1060 IF A(N,O)=ASC("X") THEN 1080
1070 GOTO 630
1080 IF A(P,Q)=ASC("X") THEN 1100
1090 GOTO 630
1100 IF A(R,S)=ASC("X") THEN 1120
1110 GOTO 630
1120 IF A(T,U)=ASC("X") THEN 1140
1130 GOTO 630
1140 PRINT"YOU HAVE DESTROYED ALL YOUR OPPONENTS-THE GAME IS YOURS"
1150 GO TO 1180
1160 PRINT"YOU TOUCHED THE FENCE !!!!!!!!!!!"
1170 PRINT "***** ZAP ***** YOU'RE DEAD!!!"
1180 PRINT "ANOTHER GAME (YES OR NO)":
1190 INPUT N9$
1200 IF N9$<>"YES" THEN 1220
1210 GO TO 220
1220 END